Module MOD_OSC
   Implicit None
   Integer, Parameter :: DP = KIND(1.d0)
   PRIVATE
   PUBLIC :: LIRE_OSC
CONTAINS
   !
   Subroutine LIRE_OSC ( fichier, itot, nchim, rayon, masse, temp, dens, lum, mue, &
                         xchim, nom_elem, ialpha)
      Character(Len=*), Intent(In) :: fichier
      Integer, Intent(Out) :: itot, nchim, ialpha
      Real(DP), Dimension(:), Allocatable, Intent(Out) :: rayon, masse, temp, dens, lum, mue
      Real(DP), Dimension(:,:), Allocatable, Intent(Out) :: xchim	
      Character(Len=4), Dimension(:), Allocatable, Intent(Out) :: nom_elem
      !
      Integer :: i, nglob, nvar, nelem, niw, ios
      Real(DP) :: somme
      Character(Len=132) :: ligne, form
      Real(DP), Dimension(:), Allocatable :: glob
      Real(DP), Dimension(:,:), Allocatable :: var
      !
      Open ( Unit=10, File=TRIM(fichier), Status="Old", Form="Formatted", &
             Action="Read", IOStat=ios)
      If ( ios /= 0 ) STOP " Pb-00 "
      !
      Read(10,"(4/)",Advance="No",IOStat=ios) 
      If ( ios /= 0 ) STOP " Pb-01 "
      Read(10,"(A)",IOStat=ios) ligne
      If ( ios /= 0 ) STOP " Pb-02 "
      !
      !   Write(*,*) "||", TRIM(ligne), "||"
      !
      Read(ligne(1:3),"(I3)",IOStat=ios) nchim
      If ( ios /= 0 ) STOP " Pb-03 "
      !
      ALLOCATE( nom_elem(nchim) , Stat=ios )
      If ( ios /= 0 ) STOP " Pb-04 "
      form = "(xx(1x,A4))"
      Write(form(2:3),"(I2.2)",IOStat=ios) nchim
      If ( ios /= 0 ) STOP " Pb-05 "
      Read(ligne(4:),TRIM(form),IOStat=ios) nom_elem(1:nchim)
      !
      Read(10,"(5I10)",IOStat=ios) itot, nglob, nvar, nelem, niw
      If ( ios /= 0 ) STOP " Pb-06 "
      If ( nelem + niw /= nchim ) Write(*,*) " Bizarre " 
      If ( niw /= 0 ) Write(*,*) " Etrange "
      !
      !   Write(*,*) itot, nglob, nvar, nelem, niw
      !
      ALLOCATE( glob(nglob) , var(nvar+nchim,itot) , Stat=ios ) 
      If ( ios /= 0 ) STOP " Pb-07 "
      Read(10,"(5ES19.12)",IOStat=ios) glob
      If ( ios /= 0 ) STOP " Pb-08 "
      !
      !   Write(*,*) glob
      !
      Do i = 1 , itot
         Read(10,"(5ES19.12)",IOStat=ios) var(:,i)
         If ( ios /= 0 ) STOP " Pb-09 "
      End Do
      !	
      CLOSE(Unit=10)
      !
      ALLOCATE( rayon(itot), masse(itot), temp(itot), dens(itot), lum(itot), mue(itot), &
                Stat=ios ) 
      If ( ios /= 0 ) STOP " Pb-10 "
      !
      Do i = 1 , itot   
         rayon(i) = var(1,i)                ! en cm
         masse(i) = 10.d0**var(2,i)         ! en g
         temp(i)  = var(3,i)                ! en K
         dens(i)  = var(5,i)                ! en g cm-3
         lum(i)   = var(7,i)                ! en erg
         mue(i)   = var(14,i)               ! en g mol-1  
      End Do                                ! n_e = avogadro * dens / mu_e   en  cm-3
      !
      If ( nvar /= 22 ) STOP " Pb-11 "
      ALLOCATE( xchim(nchim,itot) , Stat=ios ) 
      If ( ios /= 0 ) STOP " Pb-12 "
      !
      Do i = 1 , itot
         xchim(1:nchim,i) = var(nvar+1:nvar+nchim,i)       ! abondance en fraction de masse
         somme = SUM(xchim(:,i))
         If ( ABS( SUM(xchim(:,i)) - 1.0_DP ) >= 1.0e-13_DP ) Write(*,*) i, somme
      End Do
      !
      ialpha = 0
      Do i = 1 , nchim
         If ( ADJUSTL(nom_elem(i)) == "He4 " ) ialpha = i
      End Do
      !
      DEALLOCATE(glob,var)
      !
   End Subroutine LIRE_OSC
   !
End Module MOD_OSC
!!!!
!!!!
Program TEST_OSC
   USE MOD_OSC, Only: LIRE_OSC
   Implicit None
   Integer, Parameter :: DP = KIND(1.d0) , ndim = 10
   !
   Real(DP), Parameter :: masse_etoile = 1.00d0    ! A MODIFIER 
   !
   Real(DP), Dimension(:,:), Allocatable :: xchim, ychim, zchim
   Real(DP), Dimension(:), Allocatable :: rayon, masse, temp, dens, lum,      &
                                          mue, mui, mu, nel, nion, np
   Character(Len=4), Dimension(:), Allocatable :: nom_elem
   !
   Character(Len=132) :: nom_fichier
   Integer :: ios, i, nchim, ncouche, ialpha, surface, iii
   Logical :: etre_la
   !
   Real(DP), Parameter :: avogadro = 6.022e+23_dp
   !
   ! donnees locales (IL FAUT VERIFER)
   !
   Real(DP), Dimension(ndim) :: masse_chim
   Character(Len=4), Dimension(ndim) :: nom_chim
   !
   nom_chim = (/ " H1 " , "He3 " , "He4 " , "C12 " , "C13 " ,     &
                 "N14 " , "N15 " , "O16 " , "O17 " , "Si28" /)
   !
   ! pour les conversions entre les differentes types d'abondance, 
   !    je pense que les approximations entieres devraient etre suffisantes
   !                 
   masse_chim = (/ 1.0_dp  ,  3.0_dp ,  4.0_dp , 12.0_dp , 13.0_dp , &
                   14.0_dp , 15.0_dp , 16.0_dp , 17.0_dp , 28.0_dp /)
   !
   Do 
      Write(*,"(A)",Advance="No") " non du fichier a lire (sans -ad.osc) = "
      Read(*,*,IOStat=ios) nom_fichier
      If ( ios > 0 ) CYCLE
      If ( ios < 0 ) STOP " Fini "
      nom_fichier = TRIM(nom_fichier) // "-ad.osc"
      INQUIRE ( File=TRIM(nom_fichier), Exist=etre_la )
	   If ( etre_la ) EXIT
      Write(*,*) " Fichier non present "
   End Do
   !
   Write(*,*)
   Write(*,*) " Debut de la lecture des donnees "
   !
   Call LIRE_OSC ( nom_fichier, ncouche, nchim, rayon, masse, temp, dens, lum, mue,   &
                      xchim, nom_elem, ialpha)
   !
   ! autres allocations
   !
   ALLOCATE( ychim(nchim,ncouche) , zchim(nchim,ncouche) , Stat=ios ) 
   If ( ios /= 0 ) STOP " PB PB 1 "
   ALLOCATE( mui(ncouche), mu(ncouche), nel(ncouche), nion(ncouche), np(ncouche), Stat=ios ) 
   If ( ios /= 0 ) STOP " PB PB 2 "
   !
   Write(*,*) " Fin de la lecture des donnees "
   Write(*,*)
   Write(*,*) " Le nombre de couches est : ncouche = ", ncouche
   Write(*,*) " Le nombre d'elements est : nchim   = ", nchim
   If ( nchim /= ndim ) Then
      Write(*,*) " PAS LA BONNE DIMENSION DES TABLEAUX "
      STOP " PB PB PB "
   End If
   !
   Write(*,*)  " Les elements chimiques sont : "
   Do i = 1 , nchim
      Write(*,"(T40,A3,A4,A3)") "|| ", nom_elem(i), " ||"
      If ( nom_elem(i) /= nom_chim(i) ) Then
         Write(*,*) " PROBLEME d'indentification des especes ", i
      End If
   End Do
   Write(*,*)
   If ( ialpha /= 0 ) Then
      Write(*,*) " L'indice de l'helium est : " , ialpha
   Else
      Write(*,*) " Curieux mais il n'y a pas d'helium !! "
   End If
   !
   ! on cherche la surface de l'etoile
   !
   surface = MINLOC( ABS(LOG(masse/masse_etoile)) , dim=1 )
   Write(*,*) " la surface est a l'indice = ", surface
   Write(*,*)
   !
   ! on calcule les autres notions d'abondance
   ! d'abord les ychim = xchim / masse
   !
   do i = 1 , nchim
      ychim(i,:) = xchim(i,:) / masse_chim(i)
   End Do
   ! 
   ! puis le poids moleculaire par ion et total
   !
   mui(:) = 1.0_dp / SUM( ychim(:,:) , dim=1 )
   mu(:) = 1.0_dp / ( 1.0_dp / mui(:) + 1.0_dp / mue(:) ) 
   !
   ! puis les densites par volume
   !
   do i = 1 , nchim
      zchim(i,:) = ychim(i,:) * mui(:)
   End Do
   ! 
   ! les densites d'electrons et de proton en cm-3
   !
   nel(:) = avogadro * dens(:) / mue(:)
   nion(:) = avogadro * dens(:) / mui(:)
   np(:) = avogadro * dens(:) * ychim(1,:)     !  = nion(:) * zchim(1,:) 
   ! 
   ! un exemple d'affichage
   !
!   iii = surface     ! la surface i.e. temp = Teff
!   iii = ncouche     ! le centre
   iii =  245        ! la couche prise par Georges
!   iii = 450
   Write(*,*) " ON REGARDE LA COUCHE : iii = ", iii
   Write(*,*)
   !
   Write(*,*) " rayon        = ", rayon(iii)                        ! en cm
   Write(*,*) " masse        = ", masse(iii)                        ! en g
   Write(*,*) " temperature  = ", temp(iii)                         ! en K
   Write(*,*) " densite      = ", dens(iii)                         ! en g cm-3
   Write(*,*) " luminosite   = ", lum(iii)                          ! en erg s-1
   Write(*,*)
   !
   Write(*,*) " mu  = ", mu(iii)              ! en g mol-1
   Write(*,*) " mui = ", mui(iii)             ! en g mol-1
   Write(*,*) " mue = ", mue(iii)             ! en g mol-1
   Write(*,*)
   !
   Write(*,*) " nel   = ", nel(iii)           ! nel = avogadro * dens / mu_e   en  cm-3
   Write(*,*) " nion  = ", nion(iii)
   Write(*,*) " ntot  = ", avogadro * dens(iii) / mu(iii)
   Write(*,*) " np    = ", np(iii)
   Write(*,*)
   !
   ! abondance par fraction de masse (somme egale a un)
   !
   Write(*,*) " X(H)  = ", xchim(1,iii)                              ! H1   == X
!   If ( ialpha /= 0 ) Write(*,*) " Y = X(He4) = ", xchim(ialpha,iii)      ! He4  == Y (sans He3)
   Write(*,*) " X(He) = " , xchim(2,iii) + xchim(3,iii)
   Write(*,*) " X(C)  = " , xchim(4,iii) + xchim(5,iii)
   Write(*,*) " X(N)  = " , xchim(6,iii) + xchim(7,iii)
   Write(*,*) " X(O)  = " , xchim(8,iii) + xchim(9,iii)
   Write(*,*) " X(Si) = " , xchim(10,iii)
   Write(*,*)
   !
   ! abondance molaire (somme NON egale a un)
   !
   Write(*,*) " Y(H)  = " , ychim(1,iii)
   Write(*,*) " Y(He) = " , ychim(2,iii) + ychim(3,iii)
   Write(*,*) " Y(C)  = " , ychim(4,iii) + ychim(5,iii)
   Write(*,*) " Y(N)  = " , ychim(6,iii) + ychim(7,iii)
   Write(*,*) " Y(O)  = " , ychim(8,iii) + ychim(9,iii)
   Write(*,*) " Y(Si) = " , ychim(10,iii)
   Write(*,*)
   !
   ! abondance par fraction de volume (somme egale a un)
   !
   Write(*,*) " Z(H)  = " , zchim(1,iii)
   Write(*,*) " Z(He) = " , zchim(2,iii) + zchim(3,iii)
   Write(*,*) " Z(C)  = " , zchim(4,iii) + zchim(5,iii)
   Write(*,*) " Z(N)  = " , zchim(6,iii) + zchim(7,iii)
   Write(*,*) " Z(O)  = " , zchim(8,iii) + zchim(9,iii)
   Write(*,*) " Z(Si) = " , zchim(10,iii)
   Write(*,*)
   !
   ! abondance par volume (en cm-3)
   !
   Write(*,*) " n(H)  = " , nion(iii) * zchim(1,iii)
   Write(*,*) " n(He) = " , nion(iii) * ( zchim(2,iii) + zchim(3,iii) )
   Write(*,*) " n(C)  = " , nion(iii) * ( zchim(4,iii) + zchim(5,iii) )
   Write(*,*) " n(N)  = " , nion(iii) * ( zchim(6,iii) + zchim(7,iii) )
   Write(*,*) " n(O)  = " , nion(iii) * ( zchim(8,iii) + zchim(9,iii) )
   Write(*,*) " n(Si) = " , nion(iii) * zchim(10,iii)
   Write(*,*)
   !   
   DEALLOCATE(nom_elem,rayon,masse,temp,dens,lum,mue,mui,mu,nel,nion,np,xchim,ychim,zchim)
   !
   STOP "  OK "
   !
End Program TEST_OSC
!
!	var: variables
!	itot: nombre de points
!	nglob: nombre de constantes global
!	nvar: nb. de variables du tableau var sans les éléments chimiques
!	nom_elem: nom des éléments du vecteur de comp. chim. généralisée
!	nbelem: nombre d'éléments  du vecteur de comp. chim. généralisée
!	nchim: nombre d'éléments strictement chimiques
!
!	glob: variables globales du fichier mon_modele-ad.osc
!		glob(1)=mstar*msol
!		glob(2)=rtot*rsol
!		glob(3)=ltot*lsol
!		glob(4)=z0
!		glob(5)=x0
!		glob(6)=alpha
!		glob(7)=X dans ZC
!		glob(8)=Y dans ZC
!		glob(9)=d2p
!		glob(10)=d2ro
!		glob(11)=age
!		glob(12)=wrot vitesse de rotation globale
!		glob(13)=w_rot initial
!
!	var: variables locales utilisées
!
!	nvar=22 pour oscillations adiabatiques
!		var(1,i)=r*rsol
!	 	var(2,i)=log(m/mstar) -1.d38 au centre
!		var(3,i)=t
!		var(4,i)=Ptot
!		var(5,i)=ro
!		var(6,i)=gradient réel d ln T / d ln P
!		var(7,i)=l
!		var(8,i)=kap
!		var(9,i)=énergie thermo+gravifique
!		var(10,i)=grand Gamma1
!		var(11,i)=gradient adiabatique
!		var(12,i)=delta
!		var(13,i)=cp
!		var(14,i)=mu elec.
!		var(15,i)=vaissala, 0 au centre
!	 	var(16,i)=vitesse angulaire, radian/sec
!	 	var(17,i)=d ln kappa / d ln T
!	 	var(18,i)=d ln kappa / d ln ro
!	 	var(19,i)=d epsilon(nuc) / d ln T
!	 	var(20,i)=d epsilon(nuc) / d ln ro
!		var(21,i)=Ptot / Pgas
!		var(22,i)=gradient radiatif
!
!	  	var(22+j,i)=xchim(j)*nucleo(j), j=1,nchim
!
!---------------------------------------------------------------
!