C        1         2         3         4         5         6         7
C234567890123456789012345678901234567890123456789012345678901234567890123456789
C    ===================================================================
C     Selection d'un ou plusieurs champ RA,DE sur un catalogue issu de
C     SExtractor. Le centre de ces champs est lu sur un fichier externe.
C    ===================================================================

      parameter (
     1   NCMax     =      15 )          ! nombre maximum de champs

      character
     1   Nom1*40,Nom2*40,
     1   Nom3(NCMax)*40,                ! nom des catalogues extraits
     1   Nom4(NCMax)*40,
     1   Racine*10,                      ! racine de leur nom
     1   Extension*2,                   ! racine de leur extension
     1   ExtXY*3,
     1   cField*3,cSpot*1,Name(NCMax)*1,! identification des champs
     1   Ligne*80,cSgn*1

      real*8
     1   dRA,dRAh,dRAm,dRAs,
     1   dDE,dDEd,dDEm,dDEs,
     1   dRAMin(NCMax),dRAMax(NCMax),
     1   dDEMin(NCMax),dDEMax(NCMax)

      integer*4
     1   Lu3(NCMax),Lu4(NCMax),NOC(NCMax)

      logical*1
     1   InsideRA,InsideDE

C    -------------------------------------------------------------------
      CHSize    = 15.                   ! arcmin
      Nom1      = 'e446.ccd99.coo'
      Nom2      = 'e446.sex.cat'
      Racine    = 'e446.sex99'
      Extension = '.s'
      ExtXY     = '.xy'
C    ------------------------------------------------------------------
100   format ( 1x,a3,2x,a1,
     1         2x,i2,1x,i2,1x,f5.2,2x,i3,1x,i2,1x,f4.1 )
210   format ( 1x,' Lecture de l''objet :',i8 )
300   format ( 1x,i6,
     1         2x,i2,1x,i2,1x,f7.4,2x,i3,1x,i2,1x,f6.3,
     1         2x,f6.4,2x,i6,
     1         2x,f6.2,2x,f6.2,2x,f5.1,
     1         2x,f7.4,1x,f6.4,1x,i1,
     1         2x,f4.2,i3 )
400   format ( 1x,i6,
     1     2x,f8.4,1x,f8.4,
     1     2x,f8.2,1x,f8.2 )                
C    ------------------------------------------------------------------
      Lu1 = 1
      open (
     1   file   = Nom1,
     1   unit   = Lu1,
     1   status = 'old' )

      NC   = 0
      iOpt = -1
1000  CONTINUE
          read (Lu1,100,end=1100) cField,cSpot,
     1                            iRAh,iRAm,rRAs,iDEd,iDEm,rDEs
          dRAh = dble( iRAh )
          dRAm = dble( iRAm )
          dRAs = dble( rRAs )
          call DMS (dRA,dRAh,dRAm,dRAs,iOpt)
          RA   = sngl( dRA )
          dDEd = dble( iDEd )
          dDEm = dble( iDEm )
          dDEs = dble( rDEs )
          call DMS (dDE,dDEd,dDEm,dDEs,iOpt)
          DE   = sngl( dDE )

          NC = NC + 1
          if ( NC.le.NCMax ) then
              Name(NC)   = cSpot
              dRAMin(NC) = dble( RA - CHSize/(60.*15.) )
              dRAMax(NC) = dble( RA + CHSize/(60.*15.) )
              dDEMin(NC) = dble( DE - CHSize/60. )
              dDEMax(NC) = dble( DE + CHSize/60. )
          else
              print *,'>> Depassement du nombre de champs autorise <<'
          endif

          goto 1000
1100  CONTINUE
      close (Lu1)
      print *,' '
      print *,' Nb de champs a etudier :',NC
      print *,' '

      Lu2 = 2
      open (
     1    file   = Nom2,
     1    unit   = Lu2,
     1    status = 'old')
      iOpt = 1
      DO IC = 1,NC
          NOC(IC) = 0
          Lu3(IC)  = 30 + IC
          Nom3(IC) = Racine//Extension//Name(IC)
          open (
     1       file   = Nom3(IC),
     1       unit   = Lu3(IC),
     1       status = 'new' )
          Lu4(IC)  = 50 + IC
          Nom4(IC) = Racine//Extension//Name(IC)//ExtXY
          open (
     1       file   = Nom4(IC),
     1       unit   = Lu4(IC),
     1       status = 'new' )
      ENDDO

      NSaut = 68
      DO ISaut = 1,NSaut
          read (Lu2,*) Ligne
      ENDDO
      NObj = 0
2000  CONTINUE
          read (Lu2,*,end=2100)  Num,
     1                           rMagI,EMagI,rMag,iFlagM,
     1                           iRAh,iRAm,rRAs,cSgn,iDEd,iDEm,rDEs,
     1                           dRA,dDE,
     1                           XMama,YMama,
     1                           Bckg,DMax,IsoArea,
     1                           XImage,YImage,Ax,Bx,Angle,
     1                           Class,iFlagC

          NObj = NObj + 1
          if ( mod(NObj,10000).eq.0 ) then
              write (6,210) NObj
          endif

          DO IC = 1,NC
              InsideRA = dRA.ge.dRAMin(IC) .and. dRA.le.dRAMax(IC)
              InsideDE = dDE.ge.dDEMin(IC) .and. dDE.le.dDEMax(IC)
              if ( InsideRA .and. InsideDE ) then
                  NOC(IC) = NOC(IC) + 1
                  iDEd    = -iDEd
                  write (Lu3(IC),300) Num,
     1                                iRAh,iRAm,rRAs,iDEd,iDEm,rDEs,
     1                                DMax,IsoArea,
     1                                Ax,Bx,Angle,
     1                                rMag,EMagI,iFlagM,
     1                                Class,iFlagC
                  write (Lu4(IC),400) Num,
     1                                XMama,YMama,
     1                                XImage,YImage
              endif
          ENDDO

          goto 2000
2100  CONTINUE
      close (Lu2)
      DO IC = 1,NC
          close (Lu3(IC))
          close (Lu4(IC))
      ENDDO

      print *,' '
      print *,' Nb d''objets lus .... : ',NObj
      DO IC = 1,NC
          print *,' '
          print *,'Champ : ',Name(IC),' nb d''objets : ',NOC(IC)
          call DMS (dRAMin(IC),dRAh,dRAm,dRAs,iOpt)
          iRAh1 = int(sngl( dRAh ))
          iRAm1 = int(sngl( dRAm ))
          rRAs1 = sngl( dRAs )
          call DMS (dRAMax(IC),dRAh,dRAm,dRAs,iOpt)
          iRAh2 = int(sngl( dRAh ))
          iRAm2 = int(sngl( dRAm ))
          rRAs2 = sngl( dRAs )
          print *,'',iRAh1,iRAm1,rRAs1,' < RA < ',iRAh2,iRAm2,rRAs2
          call DMS (dDEMin(IC),dDEd,dDEm,dDEs,iOpt)
          iDEd1 = int(sngl( dDEd ))
          iDEm1 = int(sngl( dDEm ))
          rDEs1 = sngl( dDEs )
          call DMS (dDEMax(IC),dDEd,dDEm,dDEs,iOpt)
          iDEd2 = int(sngl( dDEd ))
          iDEm2 = int(sngl( dDEm ))
          rDEs2 = sngl( dDEs )
          print *,'',iDEd1,iDEm1,rDEs1,' < DE < ',iDEd2,iDEm2,rDEs2
      ENDDO
      
C    ===================================================================
      end

C    ===================================================================
      SubRoutine DMS (D,rD,rM,rS,iOption)
C    ===================================================================
C
C     D        : Valeur decimale.
C     rD,rM,rS : Valeurs dans le systeme degre, minutes, secondes.
C     iOption  :  +1 : Conversion syst. decimal --> syst. D,M,S
C                 -1 : Conversion syst. D,M,S   --> syst. decimal
C    ===================================================================

      real*8
     1	  D,D0,
     1	  rD,rM,rS

      if ( iOption.ge.0 ) then

          D0 = dabs( D )
          rD = dble(int( D0 ))
          rM = 60.D0*( D0 - rD )
          rS = 60.D0*( rM - dble(int( rM )) )
          rM = dble(int( rM ))

          if ( D.lt.0.D0 ) then
              if ( rD.ne.0.D0 ) then
                  rD = -1.D0* rD
              else
                  if ( rM.ne.0.D0 ) then
                      rM = -1.D0* rM
                  else
                      rS = -1.D0* rS
                  endif
              endif
          endif

      else

          D = dabs( rD ) + dabs( rM ) / 60.D0 + dabs( rS ) / 3600.D0
          if ( rD.lt.0.D0 .or. rM.lt.0.D0 .or. rS.lt.0.D0 ) then
              D = -1.D0* D
          endif

      endif

C    ===================================================================
      RETURN
      end
