      parameter
     1   NObjM       =       100000

      character
     1   Nom1*40,Nom2*40

      real*4
     1   L(NObjM),B(NObjM),
     1   R(NObjM),X(NObjM),Y(NObjM),
     1   rP1(NObjM),rP2(NObjM),rP3(NObjM)

      integer*4
     1   N(NObjM),iP1(NObjM),iP2(NObjM)

      Lu1     = 1
      Lu2     = 2

      Nom1    = 'select.rot2'
      Nom2    = 'select.uv2'
C    -------------------------------------------------------------------
      rPi     = 4.* atan( 1. )
      CDegRad = rPi / 180.
      CRadDeg = 180. / rPi
      iOption = 1
C    -------------------------------------------------------------------

      open (
     1   file   = Nom1,
     1   unit   = Lu1,
     1   status = 'old' )

      NObj = 0
1000  continue
           read (Lu1,*,end=1100) NumO,
     1                           rLong,rLat

           NObj      = NObj + 1
           N(NObj)   = NumO
           if ( rLat.gt.180. ) rLat = rLat-360.

           L(NObj)   = rLong * CDegRad
           B(NObj)   = rLat  * CDegRad
           R(NObj)   = 1.

           goto 1000
1100   continue
       close (Lu1)

       call STEREO (L,B,R,NObj,X,Y,iOption)

       open (
     1    file   = Nom2,
     1    unit   = Lu2,
     1    status = 'new' )

      DO IObj = 1,NObj
          X2 = X(IObj)
          Y2 = Y(IObj)
          write (Lu2,*) N(IObj),X2,Y2
      enddo
      close (Lu2)

C       -------------------------------------------------------------------
      end

C       ===================================================================
       SubRoutine STEREO (Alpha,Delta,Z,NPts,X,Y,iOption)
C       ===================================================================
C       Projection stereographique (ou deprojection) d'un tableau de coordonnees
C       partir du point antipodique a l'origine des coordonnees angulaires.

C       Alpha       : premiere coordonnee angulaire [0,2Pi]
C       Delta   : deuxieme coordonnee angulaire [0,2Pi]
C       Z       : coordonnee radiale
C       NPts       : nombre de points a transcrire
C       X       : abscisse sur le plan de projection
C       Y       : ordonnee sur le plan de projection
C       iOption :  1 ; projection
C                -1 ; deprojection
C       ===================================================================

       real*8
     1       dAlpha,dDelta,dZ,
     1       dsA,dcA,dsD,dcD,
     1       dU,dV,dU2,dV2,D,
     1       dPi,dPi2

       real*4
     1       Alpha(1),Delta(1),Z(1),
     1       X(1),Y(1)

C       -------------------------------------------------------------------

       if ( iOption.ge.0 ) then              ! Projection

           do IPts = 1,NPts
              dAlpha  = dble( Alpha(IPts) )
              dDelta  = dble( Delta(IPts) )
              dZ      = 2.D0* dble( Z(IPts) )
              dsA     = dsin( dAlpha )
              dcA     = dcos( dAlpha )
              dsD     = dsin( dDelta )
              dcD     = dcos( dDelta )

              D       = 1.D0 + dcA * dcD
              X(IPts) = sngl( dZ * dsA * dcD / D )
              Y(IPts) = sngl( dZ * dsD / D )
           enddo

       else                                   ! Deprojection

           dPi  = 4.D0* datan( 1.D0 )
           dPi2 = 2.D0* dPi
           do IPts = 1,NPts
              dU     = 0.5D0* dble( X(IPts) ) / dble( Z(IPts) )
              dV     = 0.5D0* dble( Y(IPts) ) / dble( Z(IPts) )
              dU2    = dU*dU
              dV2    = dV*dV

              D      = 1.D0 - dU2 - dV2
              dAlpha = datan( 2.D0* dU / D )
              if ( D.lt.0. ) then
                  dAlpha = dAlpha + dPi
              endif
              if ( dAlpha.ge.dPi2 ) then
                  dAlpha = dAlpha - dPi2
              endif
              if ( dAlpha.lt.0.D0 ) then
                  dAlpha = dAlpha + dPi2
              endif
              Alpha(IPts) = sngl( dAlpha )              ! [0;2.Pi[

              dsD    = 2.D0* dV / ( 1.D0 + dU2 + dV2 )
              dDelta = dasin( dsD )
              Delta(IPts) = sngl( dDelta )              ! [-Pi/2;Pi/2]
           enddo

      endif

C       ===================================================================
      return
      end

C       ===================================================================
       SubRoutine DMS (D,rD,rM,rS,iOption)
C       ===================================================================

C       D        : Valeur decimale.
C       rD,rM,rS : Valeurs dans le systeme degre, minutes, secondes.
C       iOption  :  +1 : Conversion syst. decimal --> syst. D,M,S
C                  -1 : Conversion syst. D,M,S   --> syst. decimal
C       ===================================================================

      real*8
     1       D,D0,
     1       rD,rM,rS

      if ( iOption.ge.0 ) then

           D0 = dabs( D )
           rD = dfloat(int( D0 ))
           rM = 60.D0*( D0 - rD )
           rS = 60.D0*( rM - dfloat(int( rM )) )
           rM = dfloat(int( rM ))

           if ( D.lt.0.D0 ) then
              if ( rD.ne.0.D0 ) then
                  rD = -1.D0* rD
              else
                  if ( rM.ne.0.D0 ) then
                     rM = -1.D0* rM
                  else
                     rS = -1.D0* rS
                  endif
              endif
           endif

      else

      D = dabs( rD ) + dabs( rM ) / 60.D0 + dabs( rS ) / 3600.D0
         if ( rD.lt.0.D0 .or. rM.lt.0.D0 .or. rS.lt.0.D0 ) then
             D = -1.D0* D
         endif

      endif

C       ===================================================================
      return
      end
